Old:Bugs 3.5-Apollo: Additional batch files

Uniform Server 3.5-Apollo known bugs or issues.

Server_Start.bat

Enhancement

Files : hdusb_server_start.bat and hdusb_server_stop.bat
Location: *Uniform Server\udrive

It is possible to run Uniform Server 3.5-Apollo at the root level of a hard disk or partition or USB stick by copying the entire contents of folder udrive to it. A virtual drive is not required; this is achieved using two new bath files as follows:

hdusb_server_start.bat

rem Name: Server_Start.bat
rem Location: Uniform Server
rem Created By: The Uniform Server Development Team
rem Edited Last By: Olajide Olaolorun (empirex)
rem Comment: After start, go to apanel directly.
rem To Developers: Implemented %www%, and %apanel% :)
rem Proposed mods MPG 14-4-2008
rem Proposed enhancement MPG 7-7-08
rem Changed path allowing bat to run at top level of drive.
rem %1 No longer required use a dummy in command line.
rem Drive letter automatically detected.

@echo off
rem working directory current folder 
pushd %~dp0

rem set current drive letter
set Disk=%~d0
set Disk=%Disk:~0,1%

rem  Command line parameters:
rem  Server_Start.bat %1 %2 %3
rem  %1 = Drive letter to use - Use a dummy drive letter
rem  %2 = mysql (run MySql server) or nomysql (do not run MySql server)
rem  %3 = console (Open a command prompt at folder MySQL Bin)
rem Note: If using %2 you must set a value for %1
rem Note: If using %3 you must set values for %1 and %2
rem Note: Default, uses drive W, runs the MySQL server and does not a command prompt.

rem ### Is Apache running if it is jump to STARTED 
rem ### First check for system error jump to Pause allows error message to be displayed.
home\admin\program\pskill.exe Apache.exe
if errorlevel 2 goto :PAUSE
if not errorlevel 1 goto :STARTED

rem ### Create variables for paths and programs 
set apachepath=\usr\local\apache2\
set apacheit=%Disk%:%apachepath%bin\Apache.exe -f %apachepath%conf\httpd.conf -d %apachepath%.
set programit=%Disk%:\home\admin\program\
set closeit=%programit%close.bat %Disk%

rem ### Change path to PHP - Required for running scripts
%Disk%:
cd \usr\local\php

rem ### Provide feedback to user
CLS
echo The server is working on the disk %Disk%:\ [http/127.0.0.1/apanel/]

rem ### Start Apache server
start %programit%uniserv.exe "%apacheit%" "%closeit%"

rem ### Start Apanel
start \home\admin\www\redirect.html

rem ### Start MySQL server - skip if requested not to start (%2)
if "%2"=="nomysql" goto :NOMYSQL
start \usr\local\mysql\bin\mysqld-opt.exe --defaults-file=/usr/local/mysql/bin/my-small.cnf
:NOMYSQL

rem ### Does user want to run a command prompt, if not END 
if "%3"=="console" goto :CONSOLE
goto :END

:CONSOLE
rem ### User wants to run a command prompt. Opens in MySQL bin
rem ### Allows command clients to be used (musql.exe and mysqladmin.exe ) 
%Disk%:
cd \usr\local\mysql\bin
start cmd.exe
goto :END

:STARTED
CLS
echo ERROR!!! 
echo One of the instances of Apache server is started. Use hdusb_server_stop.bat

:PAUSE
echo .
pause

:END

rem restore original working directory
popd

hdusb_server_stop.bat

rem Name: Stop Server File
rem Created By: The Uniform Server Development Team
rem Edited Last By: Olajide Olaolorun (empirex)
rem Comment: Tara's new syetm of shutting down the server
rem To Developers: Implemented a new system of server shutdown
rem Proposed enhancement MPG 7-7-08
rem Changed path allowing bat to run at top level of drive.


@echo off
rem working directory current folder 
pushd %~dp0

rem Stop Apache indirectly stops MySQL
:udrive\home\admin\program\pskill.exe Apache.exe c

rem Stop Apache indirectly stops MySQL changed path
home\admin\program\pskill.exe Apache.exe c

rem ### Check for system error jump to Pause allows error message to be displayed.
if errorlevel 2 goto :PAUSE
goto :END
:PAUSE
echo .
pause

:END
rem restore original working directory
popd

Download

Download files:

1. hdusb_server_start.bat.txt save as hdusb_server_start.bat
2. hdusb_server_stop.bat.txt save as hdusb_server_stop.bat

Copy both files to folder Uniform Server\udrive. Allow overwrite of existing file.

Forum reference

Additional information or background can be found on these forum pages.

None

Proposed solution

See above.

---

Ric